Wsrtjtyk

I am sorry for the newbie question regarding snakemake:

Genrally put:
What is the most elegant way to generate a workflow with two different input types in a combined way.

Let's say I have a number of samples wit different input types. Type a) is raw data in fastq format. Type b) is already assembled.

Now I want a pipeline which does assembly for all samples of type a. Next, it should do annotation with all samples (a and b).

More exemplaric:
Currently, I have a config file with the entries "samples" (type a) and "genomes" (type b).

I can generate a rule spades for samples and follow-up rule prokka for samples.
I could of course add a second rule prokka2 for genomes but how can I have a combined rule prokka for both types?

Snakemake will figure out by itself that some samples are already partially processed and it will take them forward as required. For example, given these input files:

touch s1.fq.gz s2.fq.gz s3.bam s4.bam 

This workflow will apply rule "assemble" to s1.fq.gz and s2.fq.gz only and rule annotate to all the four:

samples= ['s1', 's2', 's3', 's4']



rule all:

    input:

        expand('{sample}.annotated.bam', sample= samples)



rule assemble:

    input:

        fq= '{sample}.fq.gz'

    output:

        bam= '{sample}.bam'

    shell:

        r"""

        my_assembler {input.fq} > {output.bam}

        """



rule annotate:

    input:

        bam= '{sample}.bam'

    output:

        bam= '{sample}.annotated.bam'

    shell:

        r"""

        my_annotator {input.bam} > {output.bam}

        """

You can test the execution with Snakemake -p -n

this is how my config.yaml looks like. I just do not know how I can handle files from samples and genomes in one rule (or finde a better config solution)

samples:

 SRR653893:

  fw: SRR653893_1.fastq.gz

  rv: SRR653893_2.fastq.gz

 genomes:

   GCF:

    fasta:  GCF_000008985.1_ASM898v1_genomic.fna

@user:1114453

The example works fine, apparently because the output files of rule “assemble” for sample 3 and 4 were created beforehand.

I tried to make some structuring for the input data and results. This is my input folder

.

`-- input

    |-- s1.fq.gz

    |-- s2.fq.gz

    |-- s3.bam

    `-- s4.bam

Using snakemak (example below), I try to make assembly rule assemble for s1 and s2 and copy the already assembled rule cp_assemblies s3 and s4 to the assembly folder. Then from the assembly folder I run the annotation of all samples. How I can improve the code to deal with such situation?

samples= ['s1', 's2', 's3', 's4']

assemblies = ['s3', 's4'] 



input_dir="./input/"

results_dir="./results/"



rule all:

    input:

        expand( results_dir + 'annotation/{sample}.annotated.bam', sample= samples)



rule cp_assemblies:

    input:

        fa= input_dir + '{sample}.bam'

    output:

        bam= results_dir + 'assembly/{sample}.bam'

    shell:

        """

        cp -v -f {input.fa} > {output.bam}

        """



rule assemble:

    input:

        fq= input_dir + '{sample}.fq.gz'

    output:

        bam= results_dir + 'assembly/{sample}.bam'

    shell:

        """

        my_assembler {input.fq} > {output.bam}

        """



rule annotate:

    input:

        bam= results_dir + 'assembly/{sample}.bam'

    output:

        bam= results_dir + 'annotation/{sample}.annotated.bam'

    shell:

        """

        my_annotator {input.bam} > {output.bam}

        """