Wsrtjtyk

I'm trying to convert a .ino sketch that compiles fine to a C++ class the working code is :

byte statusLed    = 13;

byte sensorInterrupt = 0;  // 0 = digital pin 2

byte sensorPin       = 2;



// The hall-effect flow sensor outputs approximately 4.5 pulses per second per

// litre/minute of flow.

float calibrationFactor = 4.5;



volatile byte pulseCount;  



float flowRate;

unsigned int flowMilliLitres;

unsigned long totalMilliLitres;



unsigned long oldTime;



void setup()

{



  // Initialize a serial connection for reporting values to the host

  Serial.begin(38400);



  // Set up the status LED line as an output

  pinMode(statusLed, OUTPUT);

  digitalWrite(statusLed, HIGH);  // We have an active-low LED attached



  pinMode(sensorPin, INPUT);

  digitalWrite(sensorPin, HIGH);



  pulseCount        = 0;

  flowRate          = 0.0;

  flowMilliLitres   = 0;

  totalMilliLitres  = 0;

  oldTime           = 0;



  // The Hall-effect sensor is connected to pin 2 which uses interrupt 0.

  // Configured to trigger on a FALLING state change (transition from HIGH

  // state to LOW state)

  attachInterrupt(sensorInterrupt, pulseCounter, FALLING);

}



/**

 * Main program loop

 */

void loop()

{



   if((millis() - oldTime) > 1000)    // Only process counters once per second

  { 

    // Disable the interrupt while calculating flow rate and sending the value to

    // the host

    detachInterrupt(sensorInterrupt);



    // Because this loop may not complete in exactly 1 second intervals we calculate

    // the number of milliseconds that have passed since the last execution and use

    // that to scale the output. We also apply the calibrationFactor to scale the output

    // based on the number of pulses per second per units of measure (litres/minute in

    // this case) coming from the sensor.

    flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;



    // Note the time this processing pass was executed. Note that because we've

    // disabled interrupts the millis() function won't actually be incrementing right

    // at this point, but it will still return the value it was set to just before

    // interrupts went away.

    oldTime = millis();



    // Divide the flow rate in litres/minute by 60 to determine how many litres have

    // passed through the sensor in this 1 second interval, then multiply by 1000 to

    // convert to millilitres.

    flowMilliLitres = (flowRate / 60) * 1000;



    // Add the millilitres passed in this second to the cumulative total

    totalMilliLitres += flowMilliLitres;



    unsigned int frac;



    // Print the flow rate for this second in litres / minute

    Serial.print("Flow rate: ");

    Serial.print(int(flowRate));  // Print the integer part of the variable

    Serial.print(".");             // Print the decimal point

    // Determine the fractional part. The 10 multiplier gives us 1 decimal place.

    frac = (flowRate - int(flowRate)) * 10;

    Serial.print(frac, DEC) ;      // Print the fractional part of the variable

    Serial.print("L/min");

    // Print the number of litres flowed in this second

    Serial.print("  Current Liquid Flowing: ");             // Output separator

    Serial.print(flowMilliLitres);

    Serial.print("mL/Sec");



    // Print the cumulative total of litres flowed since starting

    Serial.print("  Output Liquid Quantity: ");             // Output separator

    Serial.print(totalMilliLitres);

    Serial.println("mL"); 



    // Reset the pulse counter so we can start incrementing again

    pulseCount = 0;



    // Enable the interrupt again now that we've finished sending output

    attachInterrupt(sensorInterrupt, pulseCounter, FALLING);

  }

}



/*

Insterrupt Service Routine

 */

void pulseCounter()

{

  // Increment the pulse counter

  pulseCount++;

}

My attempt to convert is the following:

the .H file:

class FlowSensor

{

public:

    FlowSensor(int pin);

    void begin();

    void run();

private:

    int _pin;

    byte sensorInterrupt = 0;  // 0 = digital pin 2



    // The hall-effect flow sensor outputs approximately 4.5 pulses per second per

    // litre/minute of flow.

    float calibrationFactor = 4.5;



    float flowRate;



    unsigned int flowMilliLitres;

    unsigned long totalMilliLitres;



    unsigned long oldTime;

    volatile unsigned long pulseCount;

    //volatile byte pulseCount;

    void pulseCounter();

};

and the C file :

FlowSensor::FlowSensor(int pin)

{

    _pin = pin;

}



void FlowSensor::begin()

{

    pinMode(_pin, INPUT);

    digitalWrite(_pin, HIGH);



    pulseCount = 0;

    flowRate = 0.0;

    flowMilliLitres = 0;

    totalMilliLitres = 0;

    oldTime = 0;



    sensorInterrupt = digitalPinToInterrupt(_pin);



    // The Hall-effect sensor is connected to pin 2 which uses interrupt 0.

    // Configured to trigger on a FALLING state change (transition from HIGH

    // state to LOW state)

    attachInterrupt(sensorInterrupt, pulseCounter, FALLING);

}



void FlowSensor::run()

{

    if ((millis() - oldTime) > 1000)    // Only process counters once per second

    {

        // Disable the interrupt while calculating flow rate and sending the value to

        // the host

        detachInterrupt(sensorInterrupt);



        // Because this loop may not complete in exactly 1 second intervals we calculate

        // the number of milliseconds that have passed since the last execution and use

        // that to scale the output. We also apply the calibrationFactor to scale the output

        // based on the number of pulses per second per units of measure (litres/minute in

        // this case) coming from the sensor.

        flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;



        // Note the time this processing pass was executed. Note that because we've

        // disabled interrupts the millis() function won't actually be incrementing right

        // at this point, but it will still return the value it was set to just before

        // interrupts went away.

        oldTime = millis();



        // Divide the flow rate in litres/minute by 60 to determine how many litres have

        // passed through the sensor in this 1 second interval, then multiply by 1000 to

        // convert to millilitres.

        flowMilliLitres = (flowRate / 60) * 1000;



        // Add the millilitres passed in this second to the cumulative total

        totalMilliLitres += flowMilliLitres;



        unsigned int frac;



        // Print the flow rate for this second in litres / minute

        Serial.print("Flow rate: ");

        Serial.print(int(flowRate));  // Print the integer part of the variable

        Serial.print(".");             // Print the decimal point

        // Determine the fractional part. The 10 multiplier gives us 1 decimal place.

        frac = (flowRate - int(flowRate)) * 10;

        Serial.print(frac, DEC);    // Print the fractional part of the variable

        Serial.print("L/min");

        // Print the number of litres flowed in this second

        Serial.print("  Current Liquid Flowing: ");          // Output separator

        Serial.print(flowMilliLitres);

        Serial.print("mL/Sec");



        // Print the cumulative total of litres flowed since starting

        Serial.print("  Output Liquid Quantity: ");          // Output separator

        Serial.print(totalMilliLitres);

        Serial.println("mL");



        // Reset the pulse counter so we can start incrementing again

        pulseCount = 0;



        // Enable the interrupt again now that we've finished sending output

        attachInterrupt(sensorInterrupt, pulseCounter, FALLING);

    }

}



/*

 * Interrupt Service Routine

 */

void FlowSensor::pulseCounter()

{

  // Increment the pulse counter

    pulseCount++;

}

The error I'm getting is:

C:UsersmarcpDropboxArduinoFlowSensorFlowSensor.cpp: In member function 'void FlowSensor::begin()':

C:UsersmarcpDropboxArduinoFlowSensorFlowSensor.cpp:24:56: error: invalid use of non-static member function

  attachInterrupt(sensorInterrupt, pulseCounter, FALLING);

                                                        ^

C:UsersmarcpDropboxArduinoFlowSensorFlowSensor.cpp: In member function 'void FlowSensor::run()':

C:UsersmarcpDropboxArduinoFlowSensorFlowSensor.cpp:80:57: error: invalid use of non-static member function

   attachInterrupt(sensorInterrupt, pulseCounter, FALLING);

Should be marked as static?

ISR must return nothing and take no arguments. That is the rule with ISR. It's just the rule, you can't change I think. Member functions all have that invisible "this" that goes along with them.

Think about it, if you had multiple instances of this class, which instance should the interrupt call from? It can't know and that is the reason you can't use member functions as ISR.

You can make a static method (so all instances share) and use a static method as an ISR but then it can't have access to any member variables. Or you can write an ISR in your sketch that calls the right method from the right instance of the class.

But you simply cannot use a member function as an ISR. It's just against the rules.